d_he3_fusion Function

function d_he3_fusion(eb) result(sigma)
    !+Calculates total cross section at a given Helium 3 energy, `eb`,
    !+for Deuterium-Helium 3 nuclear reactions in the range [0.3-4800 keV]
    !+
    !+###Equation
    !+$$ D + He3 \rightarrow He^4(3.6 MeV) + p(14.7 MeV)$$
    !+
    !+###References
    !+* Equations 8-9
    !+* Table IV, VI in Ref. 7 [[atomic_tables(module)]]
    real(Float64), intent(in) :: eb
        !+ Helium 3 energy [keV]
    real(Float64)             :: sigma
        !+ Cross Section [\(cm^2\)]

    real(Float64), dimension(5), parameter :: A1 = [ 5.7501d6,  2.5226d3, &
                                                    4.5566d1, 0.d0,  &
                                                    0.d0 ]
    real(Float64), dimension(4), parameter :: B1 = [-3.1995d-3,  -8.5530d-6, &
                                                    5.9014d-8, 0.0d0  ]

    real(Float64), dimension(5), parameter :: A2 = [-8.3993d5, 0.d0,  &
                                                     0.d0, 0.d0, 0.d0 ]
    real(Float64), dimension(4), parameter :: B2 = [-2.6830d-3, 1.1633d-6, &
                                                    -2.1332d-10, 1.4250d-14 ]

    real(Float64), parameter :: Bg = 68.7508

    real(Float64), dimension(5) :: A
    real(Float64), dimension(4) :: B
    real(Float64) :: S, E

    E = min(max(eb,0.3),4800.0)

    if(E.le.900.0) then
        A = A1
        B = B1
    else
        A = A2
        B = B2
    endif

    S = (A(1) + E*(A(2) + E*(A(3) + E*(A(4) + E*A(5))))) / &
        (1    + E*(B(1) + E*(B(2) + E*(B(3) + E*B(4)))))

    sigma = (1.0d-27)*(S/(E*exp(Bg/sqrt(E))))

end function d_he3_fusion