e_excit_2_3_janev Function

function e_excit_2_3_janev(eb) result(sigma)
    !+Calculates cross section for a electron-Hydrogen impact excitation transition from
    !+the \(n=2\) state to the \(m=3\) state at energy `eb`
    !+
    !+###Equation
    !+$$ e + H(2) \rightarrow e + H(3) $$
    !+
    !+###References
    !+* Eq. 5 in Ref. 2 [[atomic_tables(module)]]
    !+* Section 2.1.1 B in Ref. 2 [[atomic_tables(module)]]
    !+
    real(Float64), intent(in) :: eb
        !+ Collision energy [keV]
    real(Float64)             :: sigma
        !+ Cross Section [\(cm^2\)]

    real(Float64), parameter :: sigma0 = 5.984d0
    real(Float64), parameter :: deltaE = 1.8888d0
        !+ Energy difference between \(n=1\) and \(n=3\):
        !+ \(\Delta E = 13.6\left (\frac{1}{2^2} - \frac{1}{3^2}\right )\)
    real(Float64), parameter :: alpha = 1.3196d0
        !+ Fitting parameter from Section 2.1.1 B in Ref. 2
    real(Float64), dimension(5), parameter :: A = [ 38.906d0, 5.2373d0, 119.25d0, &
                                                   -595.39d0, 816.71d0]
        !+ Fitting parameters from Section 2.1.1 B in Ref. 2

    real(Float64) :: ecoll, x, s

    ecoll = eb*1.d3
    x = ecoll/deltaE
    s = A(2) + A(3)/x + A(4)/x**2.0 + A(5)/x**3.0

    sigma = 1.d-16 * sigma0/(deltaE*x) * (1.0 - 1.0/x)**alpha * (A(1)*log(x) + s)

    if(x.le.1.0) sigma = 0.d0

end function e_excit_2_3_janev